; Merkmalschablonen
Let V be [cat: V].
Let Vi be V [subcat: i].
Let Vt be V [subcat: t].
Let Vt2 be V [subcat: t2].
Let Vtp be V [subcat: tp].
Let Vp be V [subcat: p].
Let Vc be V [subcat: c].

Let N be [fs: [num: !sg]].
Let sg be [fs: [num: sg]].
Let pl be [fs: [num: pl]].
Let sg/pl be [fs: {[num: sg] [num: pl]}]

Let Det be [fs: [num: !sg]].


Parameter: Attribute Order is cat subj spec adj1 pred tense obj adj2.

Rule {Satz}
	S -> NP VP:
	<S fs subj> = <NP fs>
	<S fs> = <VP fs>.

Rule {NP mit N}
	NP -> Det (AP) N (PP) / Name:
	<NP fs spec> = <Det fs>
	<NP fs num> = <Det fs num>
	<NP fs adj1> = <AP fs>
	<NP fs adj2> = <PP fs>
	<NP fs> = <N fs>
	<NP fs> = <Name fs>.
Rule {AP}
	AP -> (Adv) A:
	<AP fs> = <A fs>
	<AP fs deg> = <Adv fs>.

Rule {PP}
	PP -> P NP:
	<PP fs> = <P fs>
	<PP fs obj> = <NP fs>.

Rule {VP mit Adjunkt (z.B. Instrumentalphrasen)}
	VP -> VP_1 PP:
	<VP fs> = <VP_1 fs>
	<VP fs adj> = <PP fs>.

Rule {VP intransitiv}
	VP -> V:
	<V subcat> = i
	<VP fs> = <V fs>.

Rule {VP transitiv}
	VP -> V NP:
	<V subcat> = t
	<VP fs> = <V fs>
	<VP fs obj> = <NP fs>.


Rule {VP bitransitiv}
	VP -> V NP_1 NP_2:
	<V subcat> = t2
	<VP fs> = <V fs>
	<VP fs obj> = <NP_2 fs>
	<VP fs obj2> = <NP_1 fs>.

Rule {VP transitiv mit PObj}
	VP -> V NP PP:
	<V subcat> = tp
	<VP fs> = <V fs>
	<VP fs obj> = <NP fs>
	<VP fs obl> = <PP fs>.

Rule {VP mit PObj}
	VP -> V PP:
	<V subcat> = p
	<VP fs> = <V fs>
	<VP fs obl> = <PP fs>.

Rule {VP Kopula}
	VP -> V {AP / NP / PP}:
	<V subcat> = c
	<VP fs> = <V fs>
	<VP fs predlink> = <AP fs>
	<VP fs predlink> = <NP fs>
	<VP fs predlink> = <PP fs>.