; Merkmalschablonen
Let V be [cat: V fs:[fin:!+]].
Let Vi be V [subcat: i].
Let Vt be V [subcat: t].
Let Vt2 be V [subcat: t2].
Let Vtp be V [subcat: tp].
Let Vp be V [subcat: p].
Let Vc be V [subcat: c].
Let Vcomp be V [subcat: comp].
Let Vtc	  be V [subcat: tcomp].
Let Vm be V [subcat: m fs: [fin: +]].

Let N be [fs: [num: !sg pers: 3]].
Let Name be [fs: [num: !sg pers: 3]].
Let sg be [fs: [num: sg]].
Let pl be [fs: [num: pl]].
Let sg/pl be [fs: {[num: sg] [num: pl]}]

Let 1sg be	sg [fs: [pers: 1]].
Let 2sg be	sg [fs: [pers: 2]].
Let 3sg be	sg [fs: [pers: 3]].
Let 1pl be	pl [fs: [pers: 1]].
Let 2pl be	pl [fs: [pers: 2]].
Let 3pl be	pl [fs: [pers: 3]].

Let 2sg/pl be	{[2sg] [pl]}.
Let 1sg/2sg/pl be	{[1sg] [2sg] [pl]}.
Let 1sg/3sg be	{[1sg] [3sg]}.
Let 2per be        sg/pl [pers: 2].

Let Det be [fs: [num: !sg]].

Let decl be <fs comp mood> = declarative.
Let int be <fs comp modd> = interrogative.


Let bare be [fs: [fin:-  vform: bare]].


Parameter: Attribute Order is cat mood subj spec adj1 pred fin vform tense obj adj2.

Rule {Satz}
	S -> NP VP:
	<S fs subj> = <NP fs>
	<S fs mood> = !declarative
	<S fs> = <VP fs>
	<VP fs fin> = +
	<NP fs num> = <VP fs num>
	<NP fs pers> = <VP fs pers>.
Rule {CP}
	CP -> C S:
	<CP fs> = <C fs>
	<CP fs> = <S fs>.

Rule {NP mit N}
	NP -> Det (AP) N (PP) / Name / Pron:
	<NP fs spec> = <Det fs>
	<NP fs num> = <Det fs num>
	<NP fs adj1> = <AP fs>
	<NP fs adj2> = <PP fs>
	<NP fs> = <N fs>
	<NP fs> = <Name fs>
	<NP fs> = <Pron fs>.
Rule {AP}
	AP -> (Adv) A:
	<AP fs> = <A fs>
	<AP fs deg> = <Adv fs>.

Rule {PP}
	PP -> P NP:
	<PP fs> = <P fs>
	<PP fs obj> = <NP fs>.

Rule {VP mit Adjunkt (z.B. Instrumentalphrasen)}
	VP -> VP_1 PP:
	<VP fs> = <VP_1 fs>
	<VP fs adj> = <PP fs>.

Rule {VP intransitiv}
	VP -> V:
	<V subcat> = i
	<VP fs> = <V fs>.

Rule {VP transitiv}
	VP -> V NP:
	<V subcat> = t
	<VP fs> = <V fs>
	<VP fs obj> = <NP fs>.


Rule {VP bitransitiv}
	VP -> V NP_1 NP_2:
	<V subcat> = t2
	<VP fs> = <V fs>
	<VP fs obj> = <NP_2 fs>
	<VP fs obj2> = <NP_1 fs>.

Rule {VP transitiv mit PObj}
	VP -> V NP PP:
	<V subcat> = tp
	<VP fs> = <V fs>
	<VP fs obj> = <NP fs>
	<VP fs obl> = <PP fs>.

Rule {VP mit PObj}
	VP -> V PP:
	<V subcat> = p
	<VP fs> = <V fs>
	<VP fs obl> = <PP fs>.

Rule {VP Kopula}
	VP -> V {AP / NP / PP}:
	<V subcat> = c
	<VP fs> = <V fs>
	<VP fs predlink> = <AP fs>
	<VP fs predlink> = <NP fs>
	<VP fs predlink> = <PP fs>.

Rule {VP comp}
	VP -> V CP:
	<V subcat> = comp
	<VP fs> = <V fs>
	<VP fs comp> = <CP fs>.

Rule {VP transitiv mit Komplement}

	VP -> V NP CP:
	<V subcat> = tcomp
	<VP fs> = <V fs>
	<VP fs obj> = <NP fs>
	<VP fs comp> = <CP fs>.

Rule  {VP mit xcomp}
	VP -> V VP_1:
	<V subcat> = m
	<VP fs> = <V fs>
	<VP fs xcomp> = <VP_1 fs>
	<VP fs xcomp fin> = -
	<VP fs xcomp vform> = bare.