; Merkmalschablonen
Let V be [cat: V fs:[copula: !- fin:!+]].

Let np/ap/pp be {[subcat: [arg1:[cat: !NP]]]
		 [subcat: [arg1:[cat: !AP]]]
		 [subcat: [arg1:[cat: !PP]]]}.

Let np/ap be {[subcat: [arg1:[cat:NP]]]
	      [subcat: [arg1:[cat:AP]]]}.

Let Vi be V	[subcat: [arg1:0 arg2:0]].
Let Vt be V	[subcat: [arg1:[cat:NP] arg2:0]].
Let Vtp be V	[subcat: [arg1:[cat:NP] arg2:[cat:PP]]].
Let Vt2 be V	[subcat: [arg1:[cat:NP] arg2:[cat:NP]]].
Let Vp be V	[subcat: [arg1:[cat:PP] arg2:0]].
Let Vc be V	np/ap/pp
		[fs: [copula: +]  subcat: [arg2:0]].
Let Vcomp be V	[subcat: [arg1:[cat:CP] arg2:0]].
Let Vtcomp be V	[subcat: [arg1:[cat:NP] arg2: [cat:CP]]].
Let Vto be V    [subcat: [arg1:[cat:VP] vform:to]].
Let Vnto be V   [subcat: [arg1:[cat:NP] arg2:[cat:VP] vform:to]].

;Let Vaci be V   [subcat: [arg1:[cat:S] vform:to]].


Let Vaux be V [subcat: [arg1:[cat:VP]]].
Let Vm be Vaux [fs: [fin:+] subcat: [vform: bare]].
Let Vdo be Vaux [subcat: [vform: bare]].
Let Vprog be Vaux [subcat: [vform: prog]].
Let Vpass be Vaux [subcat: [vform: pass]].
Let Vperf be Vaux [subcat: [vform: perf]].
Let Vbe be {[Vprog] [Vpass]}.

Let N be [fs: [num: !sg pers: 3]].
Let Name be [fs: [num: !sg pers: 3]].
Let sg be [fs: [num: sg]].
Let pl be [fs: [num: pl]].
Let sg/pl be [fs: {[num: sg] [num: pl]}].

Let 1sg be	sg [fs: [pers: 1]].
Let 2sg be	sg [fs: [pers: 2]].
Let 3sg be	sg [fs: [pers: 3]].
Let 1pl be	pl [fs: [pers: 1]].
Let 2pl be	pl [fs: [pers: 2]].
Let 3pl be	pl [fs: [pers: 3]].

Let 2sg/pl be	{[2sg] [pl]}.
Let 1sg/2sg/pl be	{[1sg] [2sg] [pl]}.
Let 1sg/3sg be	{[1sg] [3sg]}.
Let 2per be        sg/pl [pers: 2].


Let PRES be [fs: [fin: + vform: pres]].
Let ing be [fs: [fin: - vform: prog]].
Let ed1 be [fs: [fin: + vform: past]].
Let ed2 be [fs: [fin: - vform: perf]].
Let ed be {[ed1][ed2]}

Let 3sg-pres be [fs: [fin: + vform: pres num: sg pers: 3]].

Let bare be [fs: [fin:-  vform: bare]].

Let PRESENT be 1sg/2sg/pl PRES.

Let base be {[PRESENT][bare]}.

Let Det be [fs: [num: !sg]].

Let decl be <fs comp mood> = declarative.
Let int be <fs comp modd> = interrogative.


Parameter: Attribute Order is cat mood subj spec adj1 pred fin vform tense obj adj2.

Rule {Satz}
	S -> NP VP:
	<S fs subj> = <NP fs>
	<S fs mood> = !declarative
	<S fs> = <VP fs>
	<VP fs fin> = +
	<NP fs num> = <VP fs num>
	<NP fs pers> = <VP fs pers>.

Rule {CP}
	CP -> C S:
	<CP fs> = <C fs>
	<CP fs> = <S fs>.

Rule {NP mit N}
	NP -> Det (AP) N (PP) / Name / Pron:
	<NP fs spec> = <Det fs>
	<NP fs num> = <Det fs num>
	<NP fs adj1> = <AP fs>
	<NP fs adj2> = <PP fs>
	<NP fs> = <N fs>
	<NP fs> = <Name fs>
	<NP fs> = <Pron fs>.
Rule {AP}
	AP -> (Adv) A:
	<AP fs> = <A fs>
	<AP fs deg> = <Adv fs>.

Rule {PP}
	PP -> P NP:
	<PP fs> = <P fs>
	<PP fs obj> = <NP fs>.

;Rule {VP mit Adjunkt (z.B. Instrumentalphrasen)}
;	VP -> VP_1 PP:
;	<VP fs> = <VP_1 fs>
;	<VP fs adj> = <PP fs>.

Rule {VP intransitiv}
	VP -> V:
	<V subcat arg1> = 0
	<VP fs> = <V fs>.

Rule {VP transitiv}
	VP -> V NP:
	<V subcat arg1 cat> = <NP cat>
	<VP fs> = <V fs>
	<VP fs obj> = <NP fs>.


Rule {VP bitransitiv}
	VP -> V NP_1 NP_2:
	<V subcat arg1 cat> = <NP_1 cat>
	<V subcat arg2 cat> = <NP_2 cat>
	<VP fs> = <V fs>
	<VP fs obj> = <NP_2 fs>
	<VP fs obj2> = <NP_1 fs>.

Rule {VP transitiv mit PObj}
	VP -> V NP PP:
	<V subcat arg1 cat> = <NP cat>
	<V subcat arg2 cat> = <PP cat>
	<VP fs> = <V fs>
	<VP fs obj> = <NP fs>
	<VP fs obl> = <PP fs>.

Rule {VP mit PObj}
	VP -> V PP:
	<V subcat arg1 cat> = <PP cat>
	<V fs copula> = -
	<VP fs> = <V fs>
	<VP fs obl> = <PP fs>.

Rule {VP Kopula}
	VP -> V X:
	<V subcat arg1 cat> = <X cat>
	<V fs copula> = +
	<VP fs> = <V fs>
	<VP fs predlink> = <X fs>.

Rule {VP comp}
	VP -> V CP:
	<V subcat arg1 cat> = <CP cat>
	<VP fs> = <V fs>
	<VP fs comp> = <CP fs>.

Rule {VP transitiv mit Komplement}

	VP -> V NP CP:
	<V subcat arg1 cat> = <NP cat>
	<V subcat arg2 cat> = <CP cat>
	<VP fs> = <V fs>
	<VP fs obj> = <NP fs>
	<VP fs comp> = <CP fs>.

Rule  {VP mit xcomp}
	VP -> V VP_1:
	<V subcat arg1 cat> = <VP_1 cat>
	<VP fs> = <V fs>
	<VP fs xcomp> = <VP_1 fs>
	<VP fs xcomp fin> = -
	<VP fs xcomp vform> = <V subcat vform>.